home *** CD-ROM | disk | FTP | other *** search
/ Warlords / Warlords (1978) - Speakeasy Software / Warlords.dsk / WARLORDS.int < prev   
Text File  |  2022-11-03  |  15KB  |  512 lines
  1. 10 GOSUB 8000
  2. 20 GOSUB 9000
  3. 25 GOSUB 11000
  4. 30 GOSUB 1000
  5. 31 FOR X=1 TO 3000:NEXT X
  6. 32 VTAB (23):CALL -868:PRINT "NEW CAMPAIGN"
  7. 34 FOR X=1 TO 3000:NEXT X
  8. 50 C= RND (5):IF C=0 THEN 50
  9. 60 FOR N=1 TO C
  10. 70 GOSUB 7000
  11. 80 GOSUB 2000
  12. 90 NEXT N
  13. 95 VTAB (23):CALL -868:PRINT "END OF CAMPAIGN"
  14. 97 FOR X=1 TO 2000:NEXT X
  15. 98 GOSUB 4000
  16. 99 CALL -936
  17. 100 VTAB (3):TAB (10)
  18. 110 PRINT "GAME STATUS"
  19. 120 FOR X=1 TO PN
  20. 125 VTAB (X*5)
  21. 130 PRINT "WARLORD ";N$(N(X),N(X+1)-1)
  22. 135 A=0
  23. 140 FOR Z=1 TO 49
  24. 150 IF O(Z)=X THEN A=A+S(Z)
  25. 160 NEXT Z
  26. 170 PRINT "TROOPS - ";A;" DIVISIONS"
  27. 180 PRINT "CROWNS - ";PC(X);"000"
  28. 190 NEXT X
  29. 192 VTAB (24)
  30. 200 PRINT "GAME TO CONTINUE ";
  31. 210 NL=300:GOSUB 6000
  32. 215 GOSUB 10000
  33. 220 FOR X=1 TO 4000:NEXT X:GOSUB 1000
  34. 230 GOTO 31
  35. 300 END 
  36. 513 S(D)=E- RND (E/2)
  37. 1000 REM  SET UP SCREEN BORDERS
  38. 1010 CALL -936: POKE 50,63:PRINT "   ";
  39. 1020 FOR X=1 TO 7:PRINT X;"    ";:NEXT X
  40. 1030 FOR X=1 TO 22
  41. 1040 IF X MOD 3=0 THEN 1060
  42. 1050 VTAB (X):PRINT " ";:GOTO 1070
  43. 1060 PRINT X/3;
  44. 1070 TAB 38:PRINT "  "
  45. 1080 NEXT X
  46. 1090  POKE 50,255
  47. 1100 REM  LAY OUT SCREEN
  48. 1110 FOR X=1 TO 7
  49. 1120 FOR Y=1 TO 7
  50. 1130 VTAB (X*3)
  51. 1140 TAB (Y*5-2)
  52. 1145 IF T(X*7-7+Y)>1 AND T(X*7-7+Y)<4 THEN TAB (Y*5-1)
  53. 1147 IF T(X*7-7+Y)=5 THEN TAB (Y*5-1)
  54. 1150 PRINT T$(T(X*7-7+Y),T(X*7-7+Y));
  55. 1160 IF P(X*7-7+Y)#0 THEN PRINT P(X*7-7+Y);
  56. 1170 IF O(X*7-7+Y)#0 THEN PRINT O(X*7-7+Y)
  57. 1180 NEXT Y:NEXT X
  58. 1183 TAB 1:VTAB (23)
  59. 1185 PRINT "S-SWAMP,L-LAKE,F-FOREST,C-CASTLE,T-TOWN"
  60. 1187 FOR X=1 TO 1000:NEXT X
  61. 1190 FOR X=1 TO 7:FOR Y=1 TO 7
  62. 1200 IF S(X*7-7+Y)=0 THEN 1230
  63. 1210 VTAB (X*3+1):TAB (Y*5-1)
  64. 1220 PRINT S(X*7-7+Y)
  65. 1230 NEXT Y:NEXT X
  66. 1240 VTAB (23)
  67. 1250 RETURN 
  68. 2000 REM  GET BATTLE ORDERS
  69. 2010 FOR Z=1 TO PN
  70. 2020 VTAB (23):CALL -868
  71. 2021 Y=STR(Z)
  72. 2022 B=0:FOR A=1 TO 49:IF O(A)=Y THEN B=1:NEXT A:IF B#1 THEN 2999
  73. 2030 PRINT "WARLORD ";STR(Z);" ";
  74. 2050 PRINT N$(N(Y),N(Y+1)-1);" MOVE TROOPS (Y/N)";
  75. 2070 NL=2999:GOSUB 6000
  76. 2072 CALL -936: POKE 50,63:FOR X=1 TO 8
  77. 2074 VTAB (2):TAB (X*5-4):PRINT "     "
  78. 2076 VTAB (5):TAB (X*5-4):PRINT "     "
  79. 2078 VTAB (7):TAB (X*5-4):PRINT "     "
  80. 2079 VTAB (23):TAB (X*5-4):PRINT "     "
  81. 2080 NEXT X
  82. 2082  POKE 50,255
  83. 2089 VTAB (3)
  84. 2090 TAB 13:PRINT "BATTLE ORDERS"
  85. 2092 VTAB (7):PRINT "WARLORD ";Y;" ";N$(N(Y),N(Y+1)-1);
  86. 2094 PRINT " CASTLE ";(CA(Y)-1)/7+1;(CA(Y)-1) MOD 7+1
  87. 2100 VTAB (10):PRINT "FROM";:TAB (10):PRINT "TO";:TAB (20):PRINT "NUMBER OF DIVISIONS"
  88. 2110 VTAB (17):PRINT "ENTER 'FROM' AND 'TO' CO-ORDINATES AS "
  89. 2120 PRINT "ONE NUMBER IN THE FORM OF 'VH'"
  90. 2130 PRINT "WHERE 'VH' IS THE VERTICAL - "
  91. 2140 PRINT "HORIZONTAL INDEX IN THE RANGE 11-77"
  92. 2150 REM  GET FROM CO-ORDINATE
  93. 2155 FOR X=1 TO 3:VTAB (12+X):CALL -868:NEXT X
  94. 2160 VTAB (6):CALL -868
  95. 2170 VTAB (12):TAB (1):INPUT C
  96. 2171 A=C:C=(C/10*7)-7+(C MOD 10)
  97. 2172 IF A#0 THEN 2180
  98. 2175 GOSUB 1000:GOTO 2020
  99. 2180 IF A/10<1 OR A/10>7 THEN 2190
  100. 2185 IF A MOD 10>0 AND A MOD 10<8 THEN 2200
  101. 2190 VTAB (6):CALL -1052:CALL -1052:TAB (13)
  102. 2195 PRINT "CO-ORDINATE OUTSIDE RANGE":GOTO 2170
  103. 2200 REM  GET TO CO-ORDINATE
  104. 2205 FOR X=1 TO 3:VTAB (12+X):CALL -868:NEXT X
  105. 2210 VTAB (6):CALL -868
  106. 2220 VTAB (12):TAB (10):INPUT D
  107. 2221 B=D:D=(D/10*7)-7+(D MOD 10)
  108. 2222 IF B#0 THEN 2230
  109. 2225 GOSUB 1000:GOTO 2020
  110. 2230 IF B/10<1 OR B/10>7 THEN 2240
  111. 2235 IF B MOD 10>0 AND B MOD 10<8 THEN 2300
  112. 2240 VTAB (6):CALL -1052:CALL -1052
  113. 2245 CALL -868:TAB (13)
  114. 2250 PRINT "CO-ORDINATE OUTSIDE RANGE"
  115. 2260 GOTO 2220
  116. 2300 REM  GET NUMBER OF DIVISIONS
  117. 2305 FOR X=1 TO 3:VTAB (12+X):CALL -868:NEXT X
  118. 2310 VTAB (6):CALL -868
  119. 2320 VTAB (12):TAB (25):INPUT E
  120. 2330 IF E=0 THEN 2998
  121. 2340 REM  DO IT!
  122. 2350 REM  C=FROM CO-ORD
  123. 2360 REM  D=TO CO-ORD
  124. 2370 REM  E=NUMBER OF DIVISIONS
  125. 2400 IF O(C)=Y THEN 2500
  126. 2410 VTAB (6):CALL -1052:CALL -1052
  127. 2420 PRINT "NO TROOPS AT 'FROM' POSITION"
  128. 2430 GOTO 2170
  129. 2500 REM  CHECK STRENGTH
  130. 2510 IF S(C)>=E THEN 2600
  131. 2520 VTAB (6):CALL -1052:CALL -1052
  132. 2530 PRINT "NOT ENOUGH TROOPS"
  133. 2540 GOTO 2320
  134. 2600 REM  MOVE TO WHERE
  135. 2610 IF T(D)#2 THEN 2700
  136. 2620 VTAB (6):CALL -1052:CALL -1052
  137. 2630 PRINT "INVALID MOVE - LAKE "
  138. 2640 GOTO 2220
  139. 2700 GOSUB 3000:REM  LEGAL MOVE
  140. 2705 IF O(D)#0 AND O(D)#Y THEN 2800
  141. 2710 REM  OWNER OF TO CO-ORD
  142. 2715 REM   OR EMPTY CO-ORD
  143. 2720 S(D)=S(D)+E:S(C)=S(C)-E
  144. 2725 IF S(C)=0 THEN O(C)=0
  145. 2728 O(D)=Y
  146. 2730 VTAB (6):CALL -1052:CALL -1052
  147. 2735 CALL -868
  148. 2740 PRINT "MOVED ! "
  149. 2750 FOR X=1 TO 2000:NEXT X
  150. 2760 GOTO 2998
  151. 2800 GOSUB 5000:REM  BATTLE ENSUES
  152. 2998 GOSUB 1000
  153. 2999 NEXT Z:RETURN 
  154. 3000 REM  CHECK IF REQUESTED
  155. 3010 REM  MOVE IS VALID
  156. 3020 REM  C & D ARE 'FROM' AND
  157. 3030 REM  'TO' VECTOR CO-ORDS.
  158. 3040 REM  A & B ARE INPUTED BOARD
  159. 3050 REM  'MATRIX CO-ORDINATES'
  160. 3060 X=ABS (B/10-A/10)
  161. 3065 IF X>1 THEN 3100
  162. 3070 X=ABS (B MOD 10-A MOD 10)
  163. 3080 IF X>1 THEN 3100
  164. 3090 RETURN 
  165. 3100 POP :VTAB (6):CALL -1052:CALL -1052
  166. 3110 CALL -868:TAB (10):PRINT "ILLEGAL MOVE"
  167. 3120 GOTO 2170
  168. 4000 REM  CALCULATE TAXES AND RAISE
  169. 4010 REM  TROOPS
  170. 4020 REM  CASH  FROM TREASURY ONLY
  171. 4030 REM  MAY PLACE TROOPS ANY WHERE
  172. 4035 REM  ALREADY OCCUPIED BY WARLORD
  173. 4040 CALL -936
  174. 4050 FOR Z=1 TO PN
  175. 4051 CALL -936
  176. 4052 IF O(CA(Z))#Z THEN 4700
  177. 4060 VTAB (3):TAB 12:PRINT "WARLORD ";Z;" ";N$(N(Z),N(Z+1)-1)
  178. 4070 VTAB (5):PRINT "TREASURY BALANCE IS ";PC(Z)
  179. 4080 X=0
  180. 4090 FOR Y=1 TO 49
  181. 4100 IF O(Y)=Z THEN X=X+P(Y)
  182. 4110 NEXT Y
  183. 4120 VTAB (7):PRINT "TAXES RAISED THIS YEAR (000'S) ";X
  184. 4122 C=X
  185. 4125 IF PC(Z)<2 THEN 4500
  186. 4130 VTAB (9):PRINT "DO YOU WISH TO BUY TROOPS FROM TREASURY MONEY ";
  187. 4140 NL=4500:GOSUB 6000
  188. 4150 VTAB (11):CALL -868:PRINT "HOW MANY DIVISIONS ";
  189. 4160 INPUT A
  190. 4170 IF A<=PC(Z)/2 THEN 4200
  191. 4180 PRINT "DIVISIONS COST 2,000 CROWNS EACH - INSUFFICIENT CASH"
  192. 4190 VTAB (10):CALL -868:GOTO 4150
  193. 4200 GOSUB 1000:VTAB (23):CALL -958:PRINT "TROOPS TO WHAT BOARD POSITION ";
  194. 4210 INPUT B
  195. 4240 IF B/10<1 OR B/10>7 THEN 4300
  196. 4250 IF B MOD 10<1 OR B MOD 10>7 THEN 4300
  197. 4260 B=B/10*7-7+B MOD 10
  198. 4265 IF B#25 THEN 4270
  199. 4266 VTAB (23):CALL -1052:CALL -1052:CALL -868:PRINT "NOT VALID TO CAPITAL"
  200. 4268 GOTO 4295
  201. 4270 IF O(B)#Z THEN 4290
  202. 4275 CALL -936:VTAB (3):PRINT "WARLORD ";Z;" ";N$(N(Z),N(Z+1)-1)
  203. 4280 O(B)=Z:S(B)=S(B)+A:PC(Z)=PC(Z)-A*2:GOTO 4500
  204. 4290 VTAB (23):CALL -1052:CALL -1052:CALL -868:PRINT "INVALID MOVE "
  205. 4295 FOR B=1 TO 2000:NEXT B
  206. 4296 GOTO 4200
  207. 4300 VTAB (23):CALL -1052:CALL -1052:CALL -868:PRINT "INVALID BOARD POSITION "
  208. 4310 FOR B=1 TO 2000:NEXT B:GOTO 4200
  209. 4500 REM  PLACE TROOPS FROM THIS YEARS CASH 
  210. 4510 REM  MAY EXCEED THIS YEARS TAXES AS
  211. 4520 REM  THEY WILL NOW BE ADDED TO TREASURY
  212. 4530 PC(Z)=PC(Z)+C
  213. 4540 VTAB (14):CALL -868
  214. 4560 PRINT "CASH TO RAISE CASTLE TROOPS IS ";PC(Z)
  215. 4570 PRINT "DO YOU WISH TO RAISE TROOPS ";
  216. 4580 NL=4700
  217. 4590 GOSUB 6000
  218. 4600 PRINT "HOW MANY DIVISIONS (2000 EACH) ";
  219. 4610 INPUT X
  220. 4620 IF X<=PC(Z)/2 THEN 4650
  221. 4630 CALL -1052:CALL -1052
  222. 4640 PRINT "INSUFFICIENT CASH ":GOTO 4600
  223. 4650 S(CA(Z))=S(CA(Z))+X
  224. 4660 PC(Z)=PC(Z)-X*2
  225. 4700 NEXT Z
  226. 4710 RETURN 
  227. 5000 REM  BATTLE REPORT (CASUALITY LISTS)
  228. 5010 REM  FIRST CALCULATE FACTORS
  229. 5020 AS=E+T(C):DS=S(D)+T(D)
  230. 5030 IF AS>DS THEN 5100
  231. 5040 REM  DEFENDER HAS WON
  232. 5050 S(C)=S(C)-E
  233. 5055 IF S(C)=0 THEN O(C)=0
  234. 5057 IF S(D)=1 THEN 5200
  235. 5060 S(D)=S(D)- RND (S(D)/2)
  236. 5070 GOTO 5200
  237. 5100 REM  ATTACKER WINS
  238. 5110 S(C)=S(C)-E
  239. 5115 IF S(C)=0 THEN O(C)=0
  240. 5117 IF E=1 THEN 5200
  241. 5120 S(D)=E- RND (E/2)
  242. 5130 O(D)=Y
  243. 5200 RETURN 
  244. 6000 REM  ANSWER SUBROUTINE
  245. 6010 INPUT B$
  246. 6015 IF  LEN(B$)=0 THEN 6040
  247. 6020 IF  ASC(B$)=217 THEN 6070
  248. 6030 IF  ASC(B$)=206 THEN 6060
  249. 6040 PRINT "ANSWER MUST BE 'Y' OR 'N'"
  250. 6050 GOTO 6010
  251. 6060 POP :GOTO NL
  252. 6070 RETURN 
  253. 7000 REM  SET RANDOM ORDER PLAYER LIST
  254. 7010 FOR X=1 TO PN
  255. 7020 STR(X)= RND (PN+1)
  256. 7025 IF STR(X)=0 THEN 7020
  257. 7030 IF X=1 THEN 7080
  258. 7040 FOR Y=1 TO (X-1)
  259. 7050 IF STR(Y)=STR(X) THEN STR(X)=0
  260. 7060 NEXT Y
  261. 7070 IF STR(X)=0 THEN 7020
  262. 7080 NEXT X
  263. 7130 RETURN 
  264. 8000 REM  TITLE PAGE
  265. 8001 CALL -936
  266. 8010 VTAB (6)
  267. 8020 FOR X=1 TO 40:PRINT "**";:NEXT X
  268. 8025 VTAB (8)
  269. 8030 TAB 12
  270. 8040 PRINT "W A R L O R D S"
  271. 8050 FOR X=1 TO 40:PRINT "**";:NEXT X
  272. 8060 VTAB (16)
  273. 8065 TAB 5
  274. 8070 PRINT "BY : SPEAKEASY SOFTWARE LTD."
  275. 8080 VTAB (18):TAB 10
  276. 8090 PRINT "P.O. BOX 1220 "
  277. 8100 TAB 10:PRINT "KEMPTVILLE ONT."
  278. 8110 TAB 10:PRINT "CANADA K0G 1J0"
  279. 8115 FOR X=1 TO 2000:NEXT X
  280. 8120 VTAB (22)
  281. 8130 INPUT "HOW MANY PLAYERS (2-4) ",PN
  282. 8135 CALL -932
  283. 8140 IF PN<2 OR PN>4 THEN 8120
  284. 8145 DIM B$(20)
  285. 8146 DIM N(5)
  286. 8147 DIM N$(80)
  287. 8148 DIM PC(PN)
  288. 8149 DIM CA(PN)
  289. 8150 CALL -936:VTAB (3):TAB 8
  290. 8160 PRINT "WARLORDS - PLAYERS LIST"
  291. 8170 VTAB (5):FOR X=1 TO PN
  292. 8180 PRINT "ENTER NAME FOR PLAYER ";X;
  293. 8190 INPUT B$
  294. 8195 IF  LEN(B$)=0 THEN 8180
  295. 8200 Y= LEN(N$)
  296. 8210 N$(Y+1)=B$
  297. 8220 N(X)=Y+1
  298. 8225 PC(X)=0
  299. 8230 NEXT X
  300. 8235 N(X)= LEN(N$)+1
  301. 8240 DIM STR(PN)
  302. 8999 RETURN 
  303. 9000 REM  VARIABLE ALLOCATION & INIT
  304. 9001 REM  P=POPULATION
  305. 9002 REM  O=OWNERSHIP
  306. 9003 REM  T=TYPE OF CO-ORDINATE
  307. 9004 REM  S=STRENGTH OF TROOPS
  308. 9005 REM  T$=PRINT DESIGNATOR FOR T(TYPE)
  309. 9006 REM  N$=STRING VAR. FOR PLAYERS NAMES
  310. 9007 REM  B$ POS. IN N$ OF PLAYER NAME
  311. 9008 REM  N POS. IN N$ OF PLAYERS NAME
  312. 9009 REM  PC(PN) PLAYER CASH IN THOUSANDS
  313. 9010 DIM P(49)
  314. 9011 DIM O(49)
  315. 9012 DIM T(49)
  316. 9013 DIM S(49)
  317. 9014 DIM T$(7)
  318. 9020 T$=" LSTFCX"
  319. 9040 FOR X=1 TO 49
  320. 9050 P(X)=0:O(X)=0:T(X)=0:S(X)=0:NEXT X
  321. 9060 REM  INITIALIZE SCREEN MATRIX VALUES
  322. 9070 T(25)=7:P(25)=9
  323. 9080 IF PN=3 THEN 9110
  324. 9090 IF PN=2 THEN 9120
  325. 9100 T(( RND (3)+4)*7+ RND (3)+1)=6
  326. 9110 T(( RND (3)+0)*7+ RND (3)+5)=6
  327. 9120 T(( RND (3)+4)*7+ RND (3)+5)=6
  328. 9130 T(( RND (3)+0)*7+ RND (3)+1)=6
  329. 9140 REM  SET LAKES(2),SWAMPS(3),TOWNS(4) AND THEIR POPULATIONS
  330. 9150 FOR A=2 TO 4
  331. 9160 FOR X=1 TO 4
  332. 9170 Y= RND (49)+1
  333. 9180 IF T(Y)#0 THEN 9170
  334. 9190 T(Y)=A
  335. 9200 IF A#4 THEN 9210:P(Y)=4+ RND (3)
  336. 9210 NEXT X
  337. 9220 NEXT A
  338. 9230 FOR X=1 TO 10
  339. 9240 Y= RND (49)+1
  340. 9250 IF T(Y)#0 THEN 9240
  341. 9260 T(Y)=5
  342. 9270 NEXT X
  343. 9280 FOR X=1 TO 49
  344. 9290 IF T(X)#0 THEN 9330
  345. 9300 T(X)=1
  346. 9310 P(X)=1+ RND (3)
  347. 9320 GOTO 9350
  348. 9330 IF T(X)#6 THEN 9350
  349. 9340 P(X)=5+ RND (5)
  350. 9345 S(X)=9
  351. 9350 NEXT X
  352. 9360 FOR Y=1 TO PN
  353. 9370 FOR X=1 TO 49
  354. 9380 IF T(X)#6 OR O(X)#0 THEN 9390
  355. 9382 CA(Y)=X
  356. 9385 O(X)=Y:GOTO 9400
  357. 9390 NEXT X
  358. 9400 NEXT Y
  359. 9410 RETURN 
  360. 10000 REM  FATE !!
  361. 10010 X= RND (30)
  362. 10020 IF X/5=X/5+X MOD 5 THEN 10030
  363. 10025 GOTO 10999
  364. 10030 CALL -936:CALL -1052:CALL -1052
  365. 10040 VTAB (3):TAB 8:PRINT "FATE !"
  366. 10050 IF X#5 THEN 10100
  367. 10060 PRINT "PLAGUE THROUGHOUT THE LAND !"
  368. 10070 PRINT "EVERY TREASURY LOSES 5,000 CROWNS"
  369. 10072 FOR X=1 TO 3000:NEXT X
  370. 10080 FOR A=1 TO PN:PC(A)=PC(A)-5:NEXT A
  371. 10100 IF X#10 THEN 10200
  372. 10110 PRINT "BUMPER CROPS IN THE LAND OF NERD"
  373. 10120 PRINT "TREASURIES SWELL BY 10,000 CROWNS "
  374. 10122 FOR X=1 TO 3000:NEXT X
  375. 10130 FOR A=1 TO PN:PC(A)=PC(A)+10:NEXT A
  376. 10200 IF X#15 THEN 10300
  377. 10210 PRINT "MAGICIAN AEDIPIOS CASTS CURSE ON WARLORDS"
  378. 10220 PRINT "TURNS THEIR GOLD TO BLOOD"
  379. 10230 PRINT "TREASURIES WIPED OUT"
  380. 10232 FOR X=1 TO 3000:NEXT X
  381. 10240 FOR A=1 TO PN:PC(A)=0:NEXT A
  382. 10300 IF X#20 THEN 10400
  383. 10310 PRINT "BLACK DEATH STRIKES CASTLES"
  384. 10320 PRINT "HALF OF CASTLE TROOPS DIE"
  385. 10322 FOR X=1 TO 3000:NEXT X
  386. 10330 FOR A=1 TO PN:S(CA(A))=S(CA(A))/2:NEXT A
  387. 10400 IF X#25 THEN 10999
  388. 10410 PRINT "THE PHANTOMS OF TOXIS SOLANIS INVADE "
  389. 10420 PRINT "THE CAPITAL, RASCALLION DURING NIGHT"
  390. 10430 PRINT "ALL TROOPS MYSTERIOUSLY DISAPPEAR !"
  391. 10432 FOR X=1 TO 3000:NEXT X
  392. 10440 O(25)=0:S(25)=0
  393. 10999 RETURN 
  394. 11000 CALL -936:VTAB (3)
  395. 11010 PRINT "DO YOU WANT INSTRUCTIONS ?";
  396. 11020 NL=11999:GOSUB 6000
  397. 11030 REM  INSTRUCTIONS
  398. 11040 PRINT :PRINT :PRINT 
  399. 11050 PRINT "      INSTRUCTIONS FOR WARLORDS"
  400. 11060 PRINT "..............................."
  401. 11070 PRINT 
  402. 11080 PRINT "THE GAME BOARD..."
  403. 11090 PRINT "                 IS 7 BY 7 SPACES"
  404. 11100 PRINT "EACH SPACE MAY TAKE THIS FORM"
  405. 11110 PRINT :PRINT 
  406. 11120 PRINT "     C92"
  407. 11130 PRINT "      4"
  408. 11140 PRINT 
  409. 11150 PRINT "THE C STANDS FOR CASTLE ."
  410. 11160 PRINT "THE MIDDLE NUMBER..9..IS POPULATION"
  411. 11170 PRINT "THE NUMBER TO THE RIGHT IS THE WARLORD"
  412. 11180 PRINT "THE NUMBER 4 UNDERNEATH IS THE "
  413. 11190 PRINT "NUMBER OF DIVISIONS AT THIS SPACE."
  414. 11200 DIM Q$(10)
  415. 11210 PRINT :PRINT "PLEASE HIT RETURN":INPUT Q$
  416. 11220 PRINT :PRINT 
  417. 11230 PRINT "SO , A SQUARE WITH 6 DIVISIONS"
  418. 11240 PRINT "BELONGING TO WARLORD 3 AND IN A SWAMP"
  419. 11250 PRINT "WOULD LOOK LIKE THIS..."
  420. 11260 PRINT :PRINT 
  421. 11270 PRINT "     S3"
  422. 11280 PRINT "     6"
  423. 11290 PRINT 
  424. 11300 PRINT "THERE IS NO POPULATION NUMBER"
  425. 11310 PRINT "BECAUSE NO ONE LIVES IN THE SWAMPS"
  426. 11320 PRINT :PRINT 
  427. 11330 PRINT "IF YOU SEE A NUMBER ALL ALONE LIKE"
  428. 11340 PRINT :PRINT "   3"
  429. 11350 PRINT :PRINT "IT MEANS THAT IT IS OPEN COUNTRY"
  430. 11360 PRINT "AND IT IS NOT OWNED BY ANYONE."
  431. 11370 PRINT "IT ALSO DOES NOT HAVE ANY DIVISIONS."
  432. 11380 PRINT "THE 3 IS THE POPULATION COUNT."
  433. 11390 PRINT :PRINT "PLEASE HIT RETURN":INPUT Q$
  434. 11400 PRINT :PRINT "X IS THE CAPITAL."
  435. 11401 PRINT 
  436. 11410 PRINT "IF YOU SEE ...T4..."
  437. 11420 PRINT 
  438. 11430 PRINT "THIS IS A TOWN WITH A POPULATION"
  439. 11440 PRINT "COUNT OF 4 . IT IS NOT OWNED."
  440. 11450 PRINT :PRINT "IF WARLORD 1 OWNED IT"
  441. 11460 PRINT "WITH 13 DIVISIONS, IT WOULD SHOW.."
  442. 11470 PRINT :PRINT "     T41"
  443. 11480 PRINT "     13"
  444. 11490 PRINT :PRINT 
  445. 11500 PRINT "KEEP IN MIND THAT THE MORE"
  446. 11510 PRINT "POPULATION COUNTS YOU OWN"
  447. 11520 PRINT "THE MORE TAX MONEY YOU GET !!"
  448. 11530 PRINT :PRINT 
  449. 11540 PRINT "ON THE OTHER HAND ,BEING IN A "
  450. 11550 PRINT "SWAMP OR A FOREST GIVES YOU A"
  451. 11560 PRINT "MILITARY ADVANTAGE ."
  452. 11570 PRINT 
  453. 11580 PRINT "PLEASE HIT RETURN":INPUT Q$
  454. 11590 PRINT "YOU WILL GAIN A SENSE OF THE "
  455. 11600 PRINT "BATTLE STRENGTHS FROM PLAYING"
  456. 11610 PRINT "THE GAME."
  457. 11620 PRINT :PRINT 
  458. 11630 PRINT "HINT !! PROTECT YOUR CASTLE !"
  459. 11640 PRINT "IF YOU LOSE YOUR CASTLE YOU WILL"
  460. 11650 PRINT "NOT BE ABLE TO RAISE TAXES."
  461. 11660 PRINT "SHOULD YOU SUFFER SUCH A HORRIBLE"
  462. 11670 PRINT "LOSS..TRY TO GET IT BACK QUICKLY."
  463. 11675 PRINT "ALWAYS KEEP AT LEAST ONE DIVISION"
  464. 11676 PRINT "IN YOUR CASTLE !"
  465. 11680 PRINT :PRINT 
  466. 11700 PRINT "ALSO, IF YOU LOSE ALL OF YOUR"
  467. 11800 PRINT "DIVISIONS ,YOU ARE ELIMINATED !"
  468. 11810 PRINT :PRINT 
  469. 11811 PRINT "A PIECE OF PAPER TO MAKE NOTES"
  470. 11812 PRINT "AS YOU PLAY IS RECOMMENDED."
  471. 11820 PRINT :PRINT "PLEASE HIT RETURN":INPUT Q$
  472. 11830 PRINT "MOVEMENT OF DIVISIONS"
  473. 11832 PRINT "-------- -- ---------"
  474. 11834 PRINT 
  475. 11836 PRINT "YOU WILL BE TOLD WHEN IT IS YOUR"
  476. 11838 PRINT "TURN TO MOVE DIVISIONS."
  477. 11840 PRINT "ALL PLAYERS WILL HAVE THE SAME"
  478. 11842 PRINT "NUMBER OF TURNS PER CAMPAIGN BUT"
  479. 11844 PRINT "NOT IN A SET ORDER."
  480. 11846 PRINT 
  481. 11848 PRINT "YOU GIVE THE CO-ORDINATES OF THE"
  482. 11850 PRINT "SPACE YOU WANT TO MOVE DIVISIONS"
  483. 11852 PRINT "FROM FIRST...EXAMPLE :23"
  484. 11854 PRINT "FOR 2 ROWS DOWN AND 3 COLUMNS ACROSS"
  485. 11856 PRINT 
  486. 11858 PRINT "HIT RETURN BUTTON AND THEN ENTER"
  487. 11860 PRINT "CO-ORDINATES OF THE SPACE YOU"
  488. 11862 PRINT "WANT TO MOVE TO..EX: 24"
  489. 11864 PRINT 
  490. 11866 PRINT "HIT RETURN THEN ENTER NUMBER OF"
  491. 11868 PRINT "DIVISIONS YOU WANT TO MOVE."
  492. 11870 PRINT :PRINT "PLEASE HIT RETURN":INPUT Q$
  493. 11872 PRINT "IF YOU FORGET WHERE YOU ARE"
  494. 11874 PRINT "YOU CAN ENTER A ZERO IN THE"
  495. 11876 PRINT "FROM OR TO SPACE. IT WILL SHOW"
  496. 11878 PRINT "YOU THE BOARD AGAIN AND THEN"
  497. 11880 PRINT "ASK FOR YOUR MOVE."
  498. 11882 PRINT 
  499. 11884 PRINT "KEEP IN MIND THAT YOU CAN ONLY"
  500. 11886 PRINT "MOVE TO A TOUCHING SQUARE."
  501. 11888 PRINT :PRINT 
  502. 11900 PRINT "********************************"
  503. 11902 PRINT "ALL IS FAIR IN WARLORDS..YOU CAN"
  504. 11904 PRINT "MAKE ANY DIRTY DEALS YOU WANT"
  505. 11906 PRINT "TO GANG UP ON SOMEONE AND THEN"
  506. 11908 PRINT "DOUBLE-CROSS THE OTHERS."
  507. 11910 PRINT "OF COURSE..THEY CAN DO IT TO YOU TOO!"
  508. 11912 PRINT "********************************"
  509. 11914 PRINT :PRINT :PRINT :PRINT 
  510. 11990 PRINT "PLEASE HIT RETURN ":INPUT Q$
  511. 11999 RETURN 
  512.